gusucode.com > ASP+ACCESS学生论坛设计与实现(源代码+论文+开题报告) > ASP+ACCESS学生论坛设计与实现(源代码+论文+开题报告)\13学生论坛ASPAC\BBS\sendpage.asp

    <!--#include file="Conn.asp"-->
<!-- #include file="inc/const.asp" -->
<!--#include file="inc/dv_clsother.asp"-->
<!-- #include file="inc/chkinput.asp" -->
<!-- #include file="inc/email.asp" -->
<%
dim announceid
dim username
dim rootid
dim topic
dim mailbody
dim email
dim content
dim postname
dim incepts
dim announce
Dim Sql,rs
Mybbs.LoadTemplates("postjob")
Mybbs.stats=template.Strings(9)
Mybbs.Nav()
Mybbs.ShowErr()
If Cint(Mybbs.GroupSetting(15))=0 Then
	Mybbs.AddErrCode(65)
End If

If request("id")="" Then
	Mybbs.AddErrCode(43)
ElseIf Not Isnumeric(request("id")) Then
	Mybbs.AddErrCode(30)
Else
	AnnounceID=Clng(request("id"))
End If 
Mybbs.ShowErr()

Mybbs.head_var 1,Mybbs.Board_Data(4,0),"",""
	If request("action")="sendmail" Then
		If IsValidEmail(trim(Request.Form("mail")))=False Then
			Mybbs.AddErrCode(50)
		Else
			email=trim(Request.Form("mail"))
		End If
		If request("postname")="" Then
			Mybbs.AddErrCode(66)
		Else 
			postname=request("postname")
		End If
		If request("incept")="" Then
			Mybbs.AddErrCode(67)
		Else
			incepts=request("incept")
		End If
		If request("content")="" Then
			Mybbs.AddErrCode(68)
		Else
			content=Mybbs.HtmlEnCode(request("content"))
		End If
		Mybbs.ShowErr()
		Call announceinfo()
		Mybbs.ShowErr()
		if Mybbs.Forum_Setting(2)=0 Then
			Mybbs.AddErrCode(51)
		ElseIf Mybbs.Forum_Setting(2)=1 Then
			call jmail(email,topic,mailbody)
		ElseIf Mybbs.Forum_Setting(2)=2 Then
			call Cdonts(email,topic,mailbody)
		ElseIf Mybbs.Forum_Setting(2)=3 Then
			call aspemail(email,topic,mailbody)
		End If
		If SendMail="False" Then
			Mybbs.AddErrCode(51)
		End If
		Mybbs.ShowErr()
		Mybbs.Dvbbs_suc("<li>"&template.Strings(6))
	Else
		call pag()
	End If
Mybbs.ActiveOnline
Mybbs.Footer()

Sub announceinfo()
    Set rs=Mybbs.execute("select title from Dv_topic where topicID="&AnnounceID)
	If Not(rs.bof and rs.eof) then
		topic=Mybbs.HtmlEnCode(rs(0))
		rs.close:set rs=nothing
	Else
		Mybbs.AddErrCode(48)
		Exit  Sub 
	End If
	mailbody=template.html(4)&template.html(6)
	mailbody=Replace(mailbody,"{$incepts}",incepts)
	mailbody=Replace(mailbody,"{$postname}",postname)
	mailbody=Replace(mailbody,"{$bbsname}",Mybbs.Forum_Info(0))
	mailbody=Replace(mailbody,"{$boardtype}",Mybbs.Boardtype)
	mailbody=Replace(mailbody,"{$topic}",topic)
	mailbody=Replace(mailbody,"{$content}",content)
	mailbody=Replace(mailbody,"{$bbsurl}",Mybbs.Get_ScriptNameUrl)
	mailbody=Replace(mailbody,"{$boardid}",Mybbs.Boardid)
	mailbody=Replace(mailbody,"{$announceid}",announceid)
	mailbody=Replace(mailbody,"{$copyright}",Mybbs.Forum_Copyright)
	mailbody=Replace(mailbody,"{$version}",Mybbs.Forum_Version)
'	response.write mailbody
'	mailbody=""
End Sub 

Sub pag()
	Dim Tempwrite
	Tempwrite=template.html(7)
	Tempwrite=Replace(Tempwrite,"{$bbsname}",Mybbs.Forum_info(0))
	Tempwrite=Replace(Tempwrite,"{$forumurl}",Mybbs.Get_ScriptNameUrl)
	Tempwrite=Replace(Tempwrite,"{$announceid}",announceid)
	Tempwrite=Replace(Tempwrite,"{$boardid}",Mybbs.boardid)
	Response.write Tempwrite
End Sub
%>