gusucode.com > ASP+ACCESS学生论坛设计与实现(源代码+论文+开题报告) > ASP+ACCESS学生论坛设计与实现(源代码+论文+开题报告)\13学生论坛ASPAC\BBS\printpage.asp

    <!--#include file="Conn.asp"-->
<!-- #include file="inc/const.asp" -->
<!--#include file="inc/dv_clsother.asp"-->
<!--#include file="inc/dv_ubbcode.asp"-->
<%
dim sql
If Mybbs.BoardID = 0 Then
	Response.Write "参数错误"
	Response.End 
End If
Dim announceid,replyid
dim username
dim rootid
Dim topic
dim postbuyuser
Dim TotalUseTable
Dim dv_ubb
Set dv_ubb=new Dvbbs_UbbCode
abgcolor="#FFFFFF"
Mybbs.LoadTemplates("postjob")
If request("id")="" Then
	Mybbs.AddErrCode(43)
ElseIf Not Isnumeric(request("id")) Then
	Mybbs.AddErrCode(30)
Else
	AnnounceID=Clng(request("id"))
End If 
If Mybbs.GroupSetting(2)="0"  Then Mybbs.AddErrcode(31)
Mybbs.ShowErr()
Dim EmotPath
EmotPath=Split(Mybbs.Forum_emot,"|||")(0)		'em心情路径
Dim abgcolor,bgcolor
abgcolor="tablebody1"
bgcolor="tablebody2"
Call announceinfo()
Mybbs.ShowErr()
Mybbs.ActiveOnline
Mybbs.Footer()
Sub announceinfo()
	Dim rs
	Dim Tempwrite,Templist
    Set rs=Mybbs.execute("select title,PostTable from Dv_topic where topicID="&AnnounceID)
	If not(rs.bof and rs.eof) then
		TotalUseTable=rs(1)
		topic=rs(0)
	Else
		Mybbs.AddErrCode(48)
		Exit sub
	End if
	Rs.close:Set rs=Nothing
	Tempwrite=template.html(2)
	Tempwrite=Replace(Tempwrite,"{$tablewidth}",Mybbs.Mainsetting(0))
	Tempwrite=Replace(Tempwrite,"{$forumname}",Mybbs.Forum_info(0))
	Tempwrite=Replace(Tempwrite,"{$forumurl}",Mybbs.Get_ScriptNameUrl)
	Tempwrite=Replace(Tempwrite,"{$boardtype}",Mybbs.Boardtype)
	Tempwrite=Replace(Tempwrite,"{$boardid}",Mybbs.boardid)
	Tempwrite=Replace(Tempwrite,"{$topic}",Mybbs.HtmlEncode(Topic))
	Tempwrite=Replace(Tempwrite,"{$announceid}",announceid)
	
	Sql="Select b.UserName,b.Topic,b.dateandtime,b.body,u.UserGroupID,b.postbuyuser,b.Ubblist from "&TotalUseTable&" b inner join [Dv_user] u on b.PostUserID=u.userid where b.boardid="&Mybbs.boardid&" and b.rootid="&Announceid&" and b.locktopic<>2 and u.lockuser=0 order by b.announceid"
	Set rs=Mybbs.execute(Sql)
	If rs.eof and rs.bof then
		Mybbs.AddErrCode(48)
		Exit sub
	Else
		Dim i
		Sql=Rs.GetRows(-1)
		Rs.close:set Rs=nothing
		For i=0 to Ubound(sql,2)
			postbuyuser=Sql(5,i)
			Ubblists=SQL(6,i)
			username=Sql(0,i)
			Templist=Templist&template.html(3)
			Templist=Replace(Templist,"{$username}",username)
			Templist=Replace(Templist,"{$dateandtime}",Sql(2,i))
			Templist=Replace(Templist,"{$topic}",Mybbs.HtmlEncode(Sql(1,i)))
			Templist=Replace(Templist,"{$body}",SimJsReplace(dv_ubb.Dv_UbbCode(SQL(3,i),SQL(4,i),1,1)))
		Next
		Tempwrite=Replace(Tempwrite,"{$bbslist}",Templist)
		Mybbs.stats=Mybbs.HtmlEncode(Sql(1,0))
		Mybbs.head()
		Response.write Tempwrite
	End if	
End sub
Function SimJsReplace(str)
	If IsNull(str) Or str="" Then Exit Function
	str=Replace(str,"\","\\")
	str=Replace(str,"'","\'")
	SimJsReplace=str
End Function
%>